Vai al contenuto

Impostazioni cookie

Scelga per ogni tipo quali cookie consente. Può modificare la sua scelta in qualsiasi momento tramite Impostazioni cookie in fondo a ogni pagina. Informativa sulla privacy

Necessari

Sempre attivi

Servono per accedere, conservare il carrello e ricordare le sue scelte. Sono sempre attivi.

Quali cookie?
  • weboke_sessie, weboke_klant, weboke_remember: la sua sessione e la permanenza dell'accesso
  • weboke_basket: il suo carrello
  • wkBtwIncl: visualizzazione dei prezzi con o senza IVA
  • wok_cookies: la sua scelta sui cookie, 12 mesi

Misurano quale annuncio porta a una visita o a un ordine, così non paghiamo annunci che non funzionano.

Quali cookie?
  • Google Ads tramite Google Tag Manager (_gcl_au, _gcl_aw), fino a 90 giorni
  • OpenAI Ads, annunci in ChatGPT
  • wok_aff: tramite quale partner è arrivato da noi (programma di affiliazione), 60 giorni

4,6

Paese e lingua

Ogni paese ha il suo sito, con i prezzi e l'IVA di quel paese.

Vedi

Sommare il fatturato per mese o per periodo con SOMMA.PIÙ.SE

Un libro cassa, un elenco delle vendite o una registrazione delle ore hanno una data per ogni riga. Ciò che Le interessa è il totale per mese, per trimestre o tra due date, eventualmente anche per prodotto. Con SOMMA.PIÙ.SE e due condizioni sulla data può creare un riepilogo di questo tipo, che resta corretto anche quando si aggiungono nuove righe. Anche una tabella pivot può farlo (vedere Una tabella pivot per mese, trimestre o settimana); SOMMA.PIÙ.SE è più pratica quando il riepilogo deve mantenere una forma fissa, ad esempio per un rapporto o un budget.

Come esempio prendiamo le vendite di Bloemisterij Het Zonnetje nel foglio di lavoro Verkoop: in A la data, in B il prodotto, in C la categoria e in D l'importo, dalla riga 2 alla riga 300.

Passaggio 1: una serie di mesi

Crei un foglio di lavoro Riepilogo. Invece di digitare dodici date, un'unica formula le genera tutte. Digiti in A2:

=DATA.MESE(DATA(2026;1;1);SEQUENZA(12;1;0))

SEQUENZA(12;1;0) genera i numeri da 0 a 11, e DATA.MESE aggiunge altrettanti mesi al 1° gennaio 2026. Si ottiene il primo giorno di ogni mese, da A2 ad A13. Assegni ad A2:A13 il formato personalizzato mmmm aaaa (tramite Altri formati, Personalizzato, vedere Formati numerici personalizzati: "12 pz", importi in migliaia, rosso per i negativi): verrà visualizzato gennaio 2026, febbraio 2026 e così via.

Il formato data mmmm aaaa
Il formato personalizzato mmmm aaaa mostra il mese per esteso con l'anno

Passaggio 2: il fatturato per mese

Digiti in B2:

=SOMMA.PIÙ.SE(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FINE.MESE($A2;0))

SOMMA.PIÙ.SE somma gli importi la cui data è maggiore o uguale al primo giorno del mese e minore o uguale all'ultimo giorno (FINE.MESE con 0 restituisce la fine dello stesso mese). Trascini la formula fino a B13, oppure selezioni B2:B13 prima di digitare e confermi con Ctrl+Invio.

Passaggio 3: per prodotto

Inserisca i nomi dei prodotti come intestazioni uno accanto all'altro, ad esempio Rozen in C1, Tulpen in D1 e Boeket in E1, e digiti in C2:

=SOMMA.PIÙ.SE(Verkoop!$D$2:$D$300;Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FINE.MESE($A2;0);Verkoop!$B$2:$B$300;C$1)

Si aggiunge una coppia di condizioni: il prodotto deve corrispondere all'intestazione. Faccia attenzione ai simboli del dollaro: $A2 blocca la colonna dei mesi, C$1 la riga delle intestazioni. In questo modo la stessa formula può essere usata in tutto l'intervallo. Rapidamente: selezioni prima C2:E13, digiti la formula e prema Ctrl+Invio. Euro-Office inserisce allora la formula in tutte le celle selezionate, adattando i riferimenti per ogni cella.

Fatturato per mese e per prodotto
Somme per mese e per prodotto. Nella barra della formula, la formula di C2, che con C$1 fa riferimento all'intestazione Rozen (1)

Contare invece di sommare

Il numero di vendite per mese si conta con le stesse condizioni e CONTA.PIÙ.SE:

=CONTA.PIÙ.SE(Verkoop!$A$2:$A$300;">="&$A2;Verkoop!$A$2:$A$300;"<="&FINE.MESE($A2;0))

Un periodo libero

Inserisca una data di inizio in H1 e una data di fine in I1. Il fatturato compreso tra le due, inclusi entrambi i giorni:

=SOMMA.PIÙ.SE(Verkoop!D:D;Verkoop!A:A;">="&H1;Verkoop!A:A;"<="&I1)

Errori frequenti

  • Virgolette e &: il confronto va tra virgolette e la cella si aggiunge dopo con &: ">="&H1. Se digita ">=H1", Euro-Office cerca il testo H1 e il risultato è 0.
  • Date che contengono un'ora (16-11-2026 14:32) nell'ultimo giorno del mese restano escluse da "<="&FINE.MESE(...), perché questa corrisponde alla mezzanotte. In tal caso usi come seconda condizione "<"&DATA.MESE($A2;1): minore del primo giorno del mese successivo.
  • Filtrare solo per numero del mese, ad esempio con MESI() in una colonna di appoggio, somma insieme gennaio 2025 e gennaio 2026. Includa sempre anche l'anno.
  • Le date in formato testo non vengono conteggiate. Veda Date importate come testo o con giorno e mese invertiti.

Un momento…

Configuri i suoi domini

Per ogni dominio imposti i nameserver, il collegamento al suo hosting e chi ne diventa l'intestatario.

Caricamento dei suoi domini…